/* JagELFls script for ELF Debug executable */

/* Memory description */
MEMORY
{
        ram (rwx) : ORIGIN = 0x4000 , LENGTH = 0x1FC000                         /* Jaguar 2MB RAM information */
        dbg     : ORIGIN = 0, LENGTH = 0x7FFFFF
}
       
/* Sections opening */
SECTIONS
{
        .text:                                                                                                          /* Program code section */                              
        {
                . = ALIGN(2);                                                                                   /* M68000 preference alignement */
                *(.text CODE);                                                                                  /* Code section */
        } >ram
       
        .rodata:                                                                                                        /* Constant data section */
        {
                . = ALIGN(2);                                                                                   /* M68000 preference alignement */
                *(.rodata* RODATA);                                                                             /* Read-only Data section */
        } >ram
       
        .data:                                                                                                          /* Static data section */
        {
                . = ALIGN(2);                                                                                   /* M68000 preference alignement */
                *(.data DATA);                                                                                  /* Data section */
        } >ram

        .sdata:
        {
                . = ALIGN(2);                                                                                   /* M68000 preference alignement */
                *(.sdata SDATA);
        } >ram

        .bss:
        {
                . = ALIGN(2);                                                                                   /* M68000 preference alignement */
                PROVIDE(__bss_start__ = .);                                                             /* BSS start */
                *(.sbss SBSS);                                                                                  /* Small-Short BSS */
                *(.scommon SCOMMON);
                *(.bss BSS);
                *(.udata UDATA);
                *(.common COMMON);
                PROVIDE(__bss_end__ = .);                                                               /* BSS end */
                __bss_size__ = (__bss_end__-__bss_start__);                             /* BSS size */
        } >ram

        .heap:
        {
                . = ALIGN(2);                                                                                   /* M68000 preference alignement */
                PROVIDE(__HeapBase = .);                                                                
                *(.heap HEAP);
        } >ram

        .stack:
        {
                PROVIDE(__Stack = 0x200000);
        } >ram
       
        /* DWARF debug sections. */
        /* Symbols in the DWARF debugging sections are relative to the beginning of the section so we begin them at 0. */
       
        /* DWARF 1 */
        .debug 0:
        {
                *(.debug)
        } >dbg
        .line 0:
        {
                *(.line)
        } >dbg
       
        /* GNU DWARF 1 extensions */
        .debug_srcinfo 0:
        {
                *(.debug_srcinfo)
        } >dbg
        .debug_sfnames 0:
        {
                *(.debug_sfnames)
        } >dbg
       
        /* DWARF 1.1 and DWARF 2 */
        .debug_aranges 0:
        {
                *(.debug_aranges)
        } >dbg
        .debug_ranges 0:
        {
                *(.debug_ranges)
        } >dbg
        .debug_pubnames 0:
        {
                *(.debug_pubnames)
        } >dbg
       
        /* DWARF 2 */
        .debug_info 0:
        {
                *(.debug_info .gnu.linkonce.wi.*)
        } >dbg
        .debug_abbrev 0:
        {
                *(.debug_abbrev)
        } >dbg
        .debug_line 0:
        {
                *(.debug_line)
        } >dbg
        .debug_frame 0:
        {
                *(.debug_frame)
        } >dbg
        .debug_str 0:
        {
                *(.debug_str)                                   /* String table used in .debug_info */
        } >dbg
        .debug_loc 0:
        {
                *(.debug_loc)                                   /* Location lists used in the DW_AT_location attributes */
        } >dbg
        .debug_macinfo 0:
        {
                *(.debug_macinfo)                               /* Macro information */
        } >dbg
        .comment 0:
        {
                *(.comment)                                             /* ? */
        } >dbg
}